BRS: euclidean surfaces a la Cartan

[Chris Hillman]

In this thread, I plan to try to explain (with some apropos ctensor examples) in a simple and concrete context some basic techniques and notions about Riemannian two-manifolds which also apply to general Riemannian/Lorentzian manifolds.

Suppose we have a euclidean surface given by a C^2 (continuously twice differentiable) height function z=f(x,y) where x,y,z are Cartesian coordinates in euclidean-three space. In fact, to be safe we can assume f is C^\infty ("smooth", continuously differentiable to any order). In examples, f will often be real analytic (possess a two-variable McLaurin series convergent in some open neighborhood).

It is useful to write the parameterized surface in the form
$$\left[ \begin{array}{c} f \\ x \\ y \end{array} \right]$$
Then two linearly independent tangent vectors are obtained by differentiating this vector function of x,y wrt the two independent variables:
$$\partial_x = \left[ \begin{array}{c} f_x \\ 1 \\ 0 \end{array} \right], \; \; \partial_y = \left[ \begin{array}{c} f_y \\ 0 \\ 1 \end{array} \right]$$
Now taking dot products in euclidean three space by the usual vector calculus rules gives the line element written in the so-called Monge chart
$$ds^2 = (1 + f_x^2) \; dx^2 + 2 \; f_x \; f_y \; dx \; dy + (1 + f_y^2) \; dy^2$$
or more properly
$$ds^2 = (1 + f_x^2) \; dx \otimes dx + 2 \, f_x \, f_y \; dx \otimes dy + (1 + f_y^2) \; dy \otimes dy$$
In plain language: the components of the metric tensor wrt the coordinate basis are
$$\left[ \begin{array}{cc} 1 + f_x^2 & f_x \; f_y \\ f_x \; f_y & 1 + f_y^2 \end{array} \right]$$

Next we must choose a coframe, i.e. two orthogonal unit covectors
$$\sigma^1 = a_{1x} \, dx + a_{1y} \, dy, \; \sigma^2 = a_{2x} \, dx + a_{2y} \, dy$$
where we have four undetermined functions of x,y, such that
$$g = \sigma^1 \otimes \sigma^1 + \sigma^2 \otimes \sigma^2$$
(I like to use integers to index frame and coframe components, and the coordinate names to index coordinate components, when I am simply reporting the results of computation of the components of some tensor.)

That is, the metric should arise from using our covectors in place of the coordinate covectors dx,dy in the standard euclidean metric. Expanding the tensor products, we find
$$a_{1x}^2 + a_{2x}^2 = g_{xx}$$
and so forth. So the choice amounts to solving some high school algebra equations--- there will be infinitely many solutions, so we can pick any convenient one. I chose to put $a_{1y} = 0$ which gives
$$\begin{array}{rcl} \sigma^1 & = & \sqrt{\frac{1+f_x^2 + f_y^2}{1+f_y^2}} \; dx \\ \sigma^2 & = & \frac{f_x \; f_y}{\sqrt{1+f_y^2}} \; dx + \sqrt{1+f_y^2} \; dy \end{array}$$

Now we can start to compute interesting quantities, beginning with the Gaussian curvature $R_{1212}$ (components wrt the coframe, not the coordinate covectors!). I'll explain later Cartan's method for doing this working directly with the coframe; for now I just want to urge those of you who have installed Maxima to run this ctensor file in batch mode to see the results of some computations:

/* 
General E^2 manifold; cartesian Monge chart
Chart covers at most
	-infty < x,y < infty
We assume our surface is given by an embedding in E^3
	z = f(x,y)
*/
load(ctensor);
cframe_flag: true;
ratchristof: true;
ctrgsimp: true;
/* define the dimension */
dim: 2;
/* list the coordinates */
ct_coords: [x,y];
/* define variables */
depends(f,[x,y]);
/* define background metric */
lfg: ident(2);
/* define the coframe */
fri: zeromatrix(2,2);
fri[1,1]:  sqrt(1+diff(f,x)^2+diff(f,y)^2)/sqrt(1+diff(f,y)^2);
fri[2,1]:  diff(f,x)*diff(f,y)/sqrt(1+diff(f,y)^2);
fri[2,2]:  sqrt(1+diff(f,y)^2);
/* setup the spacetime definition */
cmetric();
/* display matrix whose rows give coframe covectors */
fri;
/* compute a matrix whose rows give frame vectors */
factor(fr);
/* metric tensor g_(ab) */
lg;
/* compute g^(ab) */
ug: factor(invert(lg));
christof(false);
/* Compute fully covariant Riemann components R_(mijk) = riem[i,k,j,m] */
lriemann(true);
factor(lriem[2,2,1,1]);

These computations show that the area form is
$$(1 + f_x^2 + f_y^2) \; dx \wedge dy$$
and the Gaussian curvature is
$$K = R_{1212} = \frac{ f_{xx} \; f_{yy} - f_{xy}^2 }{ \left( 1 + f_x^2 + f_y^2 \right)^2}$$
There are no further components of the Riemann tensor which are algebraically independent of this one, in two dimensions.

Incidentally, the only algebraically independent component of the Riemann tensor expanded wrt the coordinate basis is
$$R_{xyxy} = \frac{ f_{xx} \; f_{yy} - f_{xy}^2 }{ \left( 1 + f_x^2 + f_y^2 \right)}$$
which is not the Gaussian curvature. (I should caution that some authors adopt sign conventions which ensure that $R_{1212} = -K$.)

An excellent reference for surface theory (and abstract Riemannian manifolds) a la Cartan is Flanders, Differential Forms with Applications to the Physical Sciences, Dover reprint.

 

[Chris Hillman]

BRS: euclidean surfaces a la Cartan. II: Self-isometries and Killing vectors

We often encounter examples which have "metrical symmetries", i.e. self-isometries. Particularly important are continuous groups of self-isometries, which are generated by Killing vectors--- I plan to explain that later, but for now I'll assume you have some idea what I am talking about. Examples

• The paraboloid $f = (x^2+y^2)/2$ is rotationally symmetric, with Killing vector $-y \; \partial_x + x \; \partial_y$
• The surface $f = x^2/2 + y^3/3$ has no Killing vectors, but it has a reflection symmetry across y=0,
• The sphere $f = \sqrt{1-x^2-y^2}$ is a homogeneous Riemannian manifold, i.e. it has a transitive group of self-isometries; this is rather a special case because this group is actually three dimensional, which turns out to mean that the sphere is not only homogeneous but also isotropic at each point.

Unfortunately, ctensor isn't very smart about substituting the explicit definitions of f in these examples, so it is best to just make a new file. So to obtain the second example, while running the file given above in batch mode, enter the command

subst(x^2/2+y^3/3,f, fr); ev(%,diff);

Then you can paste the output into a new file, like this:

/* 
E^2 manifold; Exm 2; cartesian Monge chart
Chart covers at most
	-infty < x,y < infty

Example: f = x^2/2 + y^3/3

Run the file ManE2_cartMonge.mac, then enter this command
	subst(x^2/2+y^3/3,f, fr); ev(%,diff);
This gives the coframe we need to define this example.

Looking at the metric tensor, we see it is symmetric under y -> -y
which is a discrete symmetry.  There are no nontrivial Killing vector fields.
*/
load(ctensor);
cframe_flag: true;
ratchristof: true;
ctrgsimp: true;
/* define the dimension */
dim: 2;
/* list the coordinates */
ct_coords: [x,y];
/* define variables */
depends(f,[x,y]);
/* define background metric */
lfg: ident(2);
/* define the coframe */
fri: zeromatrix(2,2);
fri[1,1]:  sqrt(1+x^2+y^4)/sqrt(1+y^4);
fri[2,1]:  (x*y^2)/sqrt(1+y^4);
fri[2,2]:  sqrt(1+y^4);
/* setup the spacetime definition */
cmetric();
/* display matrix whose rows give coframe covectors */
fri;
/* compute a matrix whose rows give frame vectors */
factor(fr);
/* metric tensor g_(ab) */
lg;
/* compute g^(ab) */
ug: factor(invert(lg));
christof(false);
/* Compute fully covariant Riemann components R_(mijk) = riem[i,k,j,m] */
lriemann(true);
factor(lriem[2,2,1,1]);

These computations show that the line element is
$$ds^2 = (1+x^2) \; dx^2 + 2 \; x \; y^2 \; dx \; dy + (1+y^4) \; dy^2$$
where we can see that the symmetry under the reflection $y \rightarrow -y$. The dual frame defined by our coframe is
$$\begin{array}{rcl} \vec{e}_1 & = & \sqrt{\frac{1+y^4}{1+x^2+y^4}} \; \partial_x - \frac{x \; y^2}{\sqrt{1+y^2} \; \sqrt{1+x^2+y^4}} \; \partial_y \\ \vec{e}_2 & = & \frac{1}{\sqrt{1+x^2+y^4}} \; \partial_y \end{array}$$
The Gaussian curvature is
$$R_{1212} = \frac{2y}{(1+x^2+y^2)^2}$$
which shows that the coordinate line of reflection symmetry, y=0, is also the locus where the curvature vanishes.

 

[Chris Hillman]

BRS: euclidean surfaces a la Cartan. III. Visualizing frame fields

Continuing with the example $f = x^2/2+y^3/3$, in the tangent space to any point P, we can draw a little circle to scale. The idea is to think of a vector at P as a linear combination of the frame vectors at P. In particular, consider
$${\left( \vec{x} \right)}_P = \epsilon \, \cos(\alpha) \; {\left( \vec{e}_1 \right)}_P + \epsilon \, \sin(\alpha) \; {\left( \vec{e}_2 \right)}_P$$
Note that this is a vector in the tangent space to P, not a vector field. We should think of it as a small vector with base point at P. It has length $\| \vec{x} \| = \epsilon$ because, at each point, the frame vectors are orthogonal unit vectors. So as the angle [itex]\alpha[/tex] varies, this vector traces out a small circle around P (which we should think of as living in the tangent space at P).

It's useful to also draw $2 \, \epsilon \, {\left( \vec{e}_1 \right)}_P$ in red and $2 \, \epsilon \, {\left( \vec{e}_2 \right)}_P$ in blue. In more detail: choose any point $(x,y) = (x_0, y_0)$ and plug into the expressions for the frame field:
$$\begin{array}{rcl} {\left( \vec{e}_1 \right)} _P & = & \left( \sqrt{\frac{1+y_0^4}{1+x_0^2+y_0^4}}, \; - \frac{x_0 \; y_0^2}{\sqrt{1+y_0^2} \; \sqrt{1+x_0^2+y_0^4}} \right) \\ {\left( \vec{e}_2} \right)}_P & = & \left( 0, \; \frac{1}{\sqrt{1+x_0^2+y_0^4}} \right) \end{array}$$
In general, I will write vectors in a tangent space as pairs of numbers, the components taken wrt the coordinate basis at P, for reasons to become clear (I hope).

Scaling length by multiplying by $2 \, \epsilon$ we can use these to plot two small orthonormal vectors with basepoints $(x,y) = (x_0, y_0)$ (they each have length $2 \, \epsilon$ and they are aligned with the frame at the basepoint), and then a circle of radius $\epsilon$. Repeating this for some other points, you can "decorate" a map of our Riemannian two-manifold with little figures showing how the frames change as we move around. If you try this (I'm too lazy to make and upload my own figure), you should see little ellipsoids, and--- unless we are using an orthogonal chart (one such that no $dx \, dy$ terms appear in the line element written in the chart in question)--- the frame vectors will look skewed, but we can mentally adjust for the fact that this is an artifact of the "map" (in sense of "mappa Mundi", a map of the world); in fact, the frame vectors at each point P are orthonormal.

Here, it is understood that $\epsilon$ is chosen to small compared to the curvature in the region where we are drawing frames to scale. If you know about Riemann normal charts, one way to think about this is that the frame at P is related to a Riemann normal chart around P; for such a chart, it is customary to only consider a very small region around P. So each point gets its very own Riemann normal chart. (So why use frame fields? If you play around, you'll soon find that Riemann normal charts are awkward to work with, and its no fun making a new chart for each point. In contrast, frame fields are just pairs of everywhere orthogonal unit vector fields, and these turn out to be quite easy to work with!)

 

[Chris Hillman]

BRS: euclidean surfaces a la Cartan IV: a gauge freedom

When we are working with frame fields, we always enjoy a fundamental "gauge freedom": we can rotate the frames at each point, by an arbitrary angle which depends smoothly on position. Here is a ctensor file you can run in batch mode under wxmaxima, in which we have rotated the frame given in Post I for a general Riemannian manifold:

/* 
General E^2 manifold; cartesian Monge chart; rotated frame
Chart covers at most
	-infty < x,y < infty
We assume our surface is given by an embedding in E^3
	z = f(x,y)
*/
load(ctensor);
cframe_flag: true;
ratchristof: true;
ctrgsimp: true;
/* define the dimension */
dim: 2;
/* list the coordinates */
ct_coords: [x,y];
/* define variables */
depends(f,[x,y]);
depends(alpha,[x,y]);
/* define background metric */
lfg: ident(2);
/* define the coframe */
fri: zeromatrix(2,2);
fri[1,1]:  cos(alpha)*sqrt(1+diff(f,x)^2+diff(f,y)^2)/sqrt(1+diff(f,y)^2)
	-sin(alpha)*diff(f,x)*diff(f,y)/sqrt(1+diff(f,y)^2);
fri[1,2]: -sin(alpha)*sqrt(1+diff(f,y)^2);
fri[2,1]:  cos(alpha)*diff(f,x)*diff(f,y)/sqrt(1+diff(f,y)^2)
	+sin(alpha)*sqrt(1+diff(f,x)^2+diff(f,y)^2)/sqrt(1+diff(f,y)^2);
fri[2,2]:  cos(alpha)*sqrt(1+diff(f,y)^2);
/* setup the spacetime definition */
cmetric();
/* display matrix whose rows give coframe covectors */
fri;
/* compute a matrix whose rows give frame vectors */
trigsimp(factor(fr));
/* metric tensor g_(ab) */
lg;
/* compute g^(ab) */
ug: factor(invert(lg));
christof(false);
/* Compute fully covariant Riemann components R_(mijk) = riem[i,k,j,m] */
lriemann(true);
factor(lriem[2,2,1,1]);

Here is what these computations are intended to illustrate:

• the line element (and the Gaussian curvature) are unchanged, so the geometry is unchanged by our choice of a new frame field (hence the "gauge invariance")
• we spun the frame at each point by an angle $\alpha$ which varies with position, but we assume $\alpha$ is smooth (or at least C^2) on our Riemannian two-manifold.

Some fairly transparent generalizations:

• in n dimensional Riemannian manifolds, we apply an element of SO(n) at each point P, with the chosen rotation smoothly varying; then the line element is unchanged, but in general the frame components of the Riemann tensor will change. However, scalar curvature invariants will be unchanged.
• in n dimensional Lorentzian manifolds, we apply an element of $\operatorname{SO}_+(1,n)$ at each point P; then the line element is unchanged (that's the "gauge invariance") but in general the frame components of the Riemann tensor will change. However, scalar curvature invariants will be unchanged---but unlike the Riemannian case, it is possible for a curved Lorentzian manifold to have all scalar curvature invariants (conventionally taken to be polynomials in the Riemann tensor and its covariant derivatives) vanish identically, so the vanishing of curvature invariants is not a reliable indication of local flatness!

Kleinian geometry is the subject in which we construct abstract geometries from the transitive action by a Lie group of transformations (homeomorphisms) on some topological manifold (we call manifolds equipped with such an action "homogeneous spaces"). Usually we use a group which is either a matrix group or a covering group of one, so we will work with diffeomorphisms on smooth manifolds, such as a sphere or a Grassmann manifold. This is a very general approach, but all Kleinian geometries have the property that all points in the space are geometrically equivalent (because G, the group of symmetries, acts transitively).

Cartanian geometry is the subject which unifies Kleinian geometry and Riemannian/Lorentzian geometry. The general idea is to make a frame bundle over our space, and also a G-bundle where G is our "principal group". Then a smooth section in the frame bundle is a frame field, and a smooth section in the G-bundle acts on that frame by apply a particular element of G at each point P. Then we can consider various groups G in addition to SO(n+1) and SO(1,n), such as the general linear group, or a group of volume preserving transformations, or... It turns out that in general we define a Cartan geometry on a smooth manifold M by giving a Cartan connection (a one-form on M, taking values in the Lie algebra of G), and we characterize the geometry using curvature (a two-form on M, taking values in the Lie algebra of G) and torsion (another two-form on M, taking values in the Lie algebra of G). There are subtle issues of local versus globally defined sections in the bundles. The book by Flanders offers a very readable introduction to Cartanian geometry; more detail can be found in Sharpe, Differential Geometry, Springer, GTM 166. (And if that's GTM 166, you don't even want to meet GTM 666.)

Cartanian geometry is in fact the context in which Weyl invented the notion of "gauge transformation". He considered the group generated by rotations, boosts, and dilations, and constructed the appropriate generalization of general relativity, using field equations defined for these slightly non-Lorentzian manifolds. This is a theory in which, when you parallel transport a frame in a small loop, in general it comes back rotated and boosted (as in Lorentzian geometry) and rescaled. Einstein immediately pointed out that if so, atoms would not have a fixed size, and that was the end of Weyl's gravitation theory! But of course his mathematical idea was very good.

Recently, there has been renewed interest in theories in which one uses a connection with zero curvature but nonzero torsion. It turns out that one can approximate gtr using such theories, which have the signal advantage that energy and momentum of the gravitational field are well defined! Unfortunately, these theories have so far proven difficult to work with.

From time to time, you'll see posters asking about formulating fundamental physics in terms of ideas about crystalline dislocations. These are associated in Cartianian geometries with a nonzero torsion tensor.