Fun with Carminati-McLenaghan invariants

[bcrowell]

There is a set of 16 polynomial curvature scalars called the Carminati-McLenaghan invariants: https://en.wikipedia.org/wiki/Carminati–McLenaghan_invariants . For some fairly broad classes of spacetimes, they are supposed to give enough information to distinguish one spacetime from another. As far as I know, they have been implemented in GRTensorII (a free package that runs on top of the proprietary Maple CAS), but not in Maxima/ctensor, which is free. I thought I would try to implement some of them in Maxima. So far, I've implemented the first four on the list, which are called $R$, $R_1$, $R_2$, $R_3$. This is a learning experience for me, since I haven't done much actual coding in Maxima before. The following is the code I came up with:

/*-----------------------------------------------------------------
  Carminati-McLenaghan invariants,
  https://en.wikipedia.org/wiki/Carminati%E2%80%93McLenaghan_invariants
  (c) 2015 B. Crowell, GPL v. 2 licensed
 ------------------------------------------------------------------*/

/* Make sure the following have been calculated: */
cmetric(false)$
lriemann(false)$
uriemann(false)$
ricci(false)$ /* compute the ricci tensor ric[i,j]=R_ij */
uricci(false)$ /* compute the mixed ricci tensor uric[i,j]=R_i^j */

/* R=R_i^i, the Ricci scalar, scalar curvature */
cm_r():=trigsimp(ratsimp(sum(uric[i,i],i,1,dim)))$
cm_r();

/* trace-free Ricci tensor, cm_s[i,j]=S_ij=R_ij-(1/4)Rg_ij */
for i thru dim do
  for j thru dim do
  cm_s[i,j] : ric[i,j]-(1/4)*cm_r()*lg[i,j]$
/* mixed version, cm_us[i,j]=S^i_j */
for i thru dim do
  for j thru dim do
  cm_us[i,j] : sum(ug[i,k]*cm_s[k,j],k,1,dim)$

/* R_1=(1/4)S^i_j S^j_i */
cm_r1():=trigsimp(ratsimp((1/4)*sum(sum(cm_us[i,j]*cm_us[j,i],j,1,dim),i,1,dim)))$
cm_r1();

/* R_2=(-1/8)S^i_j S^j_k S^k_i */
cm_r2():=trigsimp(ratsimp((-1/9)*sum(sum(sum(cm_us[i,j]*cm_us[j,k]*cm_us[k,i],k,1,dim),j,1,dim),i,1,dim)))$
cm_r2();

/* R_3=(1/16)S^i_j S^j_k S^k_l S^l_i */
cm_r3():=trigsimp(ratsimp((1/16)*sum(sum(sum(sum(cm_us[i,j]*cm_us[j,k]*cm_us[k,l]*cm_us[l,i],
  l,1,dim),k,1,dim),j,1,dim),i,1,dim)))$
cm_r3();

I tried it out on the following four metrics:

I. Schwarzschild

II. de Sitter space

III. $ds^2 =d u d v-a^2(u)d w^2$, with $a(u)=1+\cos(u)/2$ -- see
Schmidt, "Why do all the curvature invariants of a gravitational wave vanish?" http://arxiv.org/abs/gr-qc/9404037[/PLAIN]

IV. $ds^2 = A(t)(dt^2-dx^2)$, with $A(t)=1/(1+e^t)$ -- see https://www.physicsforums.com/threads/curvature-singularity-with-well-behaved-kretschmann-scalar.842614/#post-5290133

I. Schwarzschild. This gave zero for all four of the invariants that I'd implemented. I assume that the Kretschmann invariant is algebraically independent of these, but that if I implement the other 12 invariants, at least one will detect the singularity in the same way the the Kretschmann invariant does.

II. de Sitter space. R=-12, and the other three are zero. It makes sense that they're all constant, since de Sitter space doesn't evolve over time.

III. All four of the invariants I'd implemented vanish, as they should for this solution. (That's the point of the Schmidt paper.)

IV. All four are nonzero and approach a finite limit as $t\rightarrow\infty$, even though there is geodesic incompleteness. It would be interesting to see if one of the other 12 invariants does blow up as $t\rightarrow\infty$. If not, then it would support @PAllen 's suspicion that this spacetime could be extended past the singularity and so is not really singular.

It would be interesting to implement the other 12 invariants. Do do that, I would have to figure out how to compute the dual $^*C$ of the Weyl tensor.

 

[bcrowell]

The rest of the CM invariants have definitions that involve the Hodge dual of the Weyl tensor, which the WP article writes as $^*C_{\kappa\lambda\mu\nu}$. This confuses me somewhat, since I would ordinarily have thought that the Hodge dual of a rank k=4 tensor in n=4 dimensions would have rank n-k=0. However, I found the following reference through a google search that seems to define it:

Due to the Lanczos identity, see e.g.[5], the Weyl tensor has only one independent Hodge dual in 4 dimensions, given by $^*C_{\alpha\beta\mu\nu}=(1/2)\eta_{\mu\nu\rho\sigma}C_{\alpha\beta}^{\rho\sigma}=(1/2)\eta_{\alpha\beta\rho\sigma}C^{\rho\sigma}_{\mu\nu}$

--Reference Frames and Gravitomagnetism, edited by J F Pascual-Sánchez, L Floría, A San Miguel, F Vicente, https://books.google.com/books?id=A...=onepage&q="weyl tensor" "hodge dual"&f=false

This seems a little ad hoc to me, although maybe I'd see the motivation if I figured out what the Lanczos identity was about. I assume their $\eta$ is what most people call $\epsilon$, i.e., the Levi-Civita tensor. It does make sense in terms of the rank of the result and the fact that the Weyl tensor is antisymmetric on the first pair and final pair of indices, so that when you consider these indices, it acts like a 2-form.

One thing that this makes me wonder about is whether the CM invariants are only defined on an orientable spacetime. Or does it not matter, since the invariants are all of even order in the Weyl tensor, so that you can throw in any sign you like without affecting the results?

So now I'm trying to figure out if I understand this well enough to implement it in Maxima code. How does one go about calculating this in a space that isn't flat? Is the $\eta$ here going to be normalized such that its components are -1, 0, and 1 at every point, or do we have to throw in factors of $\sqrt{-g}$? MTW has a discussion of this sort of thing on pp. 87-88, and they use their $\epsilon$. I believe MTW defines both an $\epsilon_{0123}$ notation and a $[0123]$, with one being normalized and the other tensorial, but I can't remember which is which.

 

[bcrowell]

I now have an implementation of all the CM invariants: https://github.com/bcrowell/cm_invariants . Maybe this would be of use to others. I've tested it on several different spacetimes, and although the results seem to make sense, I don't actually have any published results to compare with so that I can test the software in known cases.