Dismiss Notice
Join Physics Forums Today!
The friendliest, high quality science and math community on the planet! Everyone who loves science is here!

Magnetic Fields of a Relativistic Charged Particle

  1. Apr 29, 2013 #1


    User Avatar
    Gold Member

    Where can I find a picture of the magnetic field lines produced by a charged particle moving near the speed of light?

    Is there a formula for the strength of B and direction of field lines as v --> c? Does this equation reduce to Ampere's right hand rule for a moving charge's ability to create classical circular magnetic field lines when the particle's velocity is non-relativistic? Is there an animation somewhere that shows the transition from circular, Ampere field lines at everyday velocities to relativistic field lines as the charged particle gets faster?

    I know that the electric field lines go from spherically symmetric to being bunched up like "Broomstick Hairs." I know that in relativity, E can be B in another frame and vice versa, but I'm not looking for transformations. I'm just watching the high energy particle go by and looking at its field lines.
    Last edited: Apr 29, 2013
  2. jcsd
  3. Apr 29, 2013 #2


    User Avatar
    Gold Member

    Also, I don't want to know about synchotron radiation or anything where the charged particle produces radiation. Those are cases for charged particle feeling an external field. I want to know about field lines created by relativistic particles.
  4. Apr 29, 2013 #3


    User Avatar

    Staff: Mentor

  5. Apr 30, 2013 #4


    User Avatar
    Science Advisor

    You will find the magnetic field of a moving charge by applying the Lorentz-transformation to the static Coulomb field of a charge at rest. The transformation mixes electric and magnetic fields. So instead of solving the equations for a moving charge one can start with the charge at rest, and then apply the transformation. That means we can equally well say that the charge is still at rest, we as observers are moving with some velocity relative to the rest frame of the charge, and we therefore see electric plus magnetic fields.

    Setting c=1 and using that the B-field vanishes in the rest frame we find

    [tex]B^\prime = - \gamma\;v \times E[/tex]

  6. Apr 30, 2013 #5


    Staff: Mentor

    Sure, but as the previous posters pointed out, the easiest way to calculate the field lines of a particle in uniform motion is by using the transforms.

    If you have a particle that is not moving uniformly then the correct equations are given by the Lienard Wiechert fields:


    This is the complete relativistically correct expression for the fields from a point particle moving arbitrarily.
  7. Aug 29, 2013 #6
    I had the same problem an could find none, so I did it myself.

    Of course there is. They are just Lorentz transformations of the EM tensor passing from the reference system in which the charge is at rest to a reference system in which it's moving with speed -v: in SI units,

    [itex] E'x = Ex [/itex]
    [itex] E'y = γ(Ey − v Bz ) [/itex]
    [itex] E'z = γ(Ez + v By ) [/itex]

    [itex] B'x = Bx [/itex]
    [itex] B'y = γ(By + β/c Ez ) [/itex]
    [itex] B'z = γ(Bz − β/c Ey ) [/itex]

    Yes: in the above formulas, if S is the reference where the charge is at rest, Bx=By=Bz=0, and the last two become

    [itex] B'y = γ( β/c Ez ) [/itex]
    [itex] B'z = γ( − β/c Ey ) [/itex]

    If γ ≈ 1, at low speeds, you obtain the Biot-Savart law for a non relativistic moving particle.

    I'm afraid you have to do it yourself. I enclose below the gnuplot tool with which you can plot the field lines for several values of beta, and then join plots together in an animated gif. I'll try to do it, but it will take a while (both for me and for my CPU's).

    For now, have a look to the transition of lines for:

    v = 0.01 c << c (gamma = 1.00005..)
    v = c/2 (gamma = 1.1547..)
    v = c sqrt(3.)/2.(gamma = 2)
    v = .99 c (gamma = 7.09..)

    But before, let me explain the meaning of lines you'll see. To represent a vector field in a 3D space several choices can be made: e.g. little arrows here and there, or flux lines... Here, we can rely on the intrinsic problem's cylindrical simmetry, and concentrate to a xy plane, where x-axis is the charge's trajectory and y-axis is any straight line orthogonal to x passing throught the charge's instantaneous position. At any point of the xy plane, E is radial, i.e. directed to or from the charge in the origin (even at relativistic speeds); and B is orthogonal to the plane. So, the only additional information needed for each point is absolute value of fields: |E| and |B|.

    I represent them with "level curves" iso|E| and iso|B|, lines where |E| and |B| have the same value (seen in legend).

    In the first figure (non-relativistic speed), you can easily recognize iso|E| isolines: they are nearly perfect concentric circles. Other isolines are iso|B|.

    Increasing v, isolines are deformed, but they remain recognizable.

    Remember, the magnetic field flux lines are orthogonal to the screen, entering in it in a sempilane delimited by the x-axis and emerging from it in the other semiplane.

    v << c (gamma = 1.00005..):


    v = c/2 (gamma = 1.1547..):


    v = c sqrt(3.)/2. such that gamma = 2


    v = .99 c (gamma = 7.09..)


    Yes, I understand the problem: nearly all web pages found by Google with obvious appropriate keywords treat point charges moving in a field, not field generated by them :-(

    The gnuplot script:

    Code (Text):

    # gnuplot commands

    # natural units system:
      c = 1.
      eps0 = 1.

    # unitary charge
      q = 1.

    # uncomment desired velocity
    # or write it in gnuplot command line
    #   before pasting the whole script

    # v << c (gamma = 1.00005..):
    # v = .01

    # v = c/2 (gamma = 1.1547..):
    # v = .5

    # v such that gamma = 2
    # v = sqrt(3.)/2.

    # v/c = .99 (gamma = 7.09..)
    # v = .99

    # v/c = .999 (gamma = 22.4)
    # v = .999

    # v/c = .9999 (gamma = 70)
    # v = .9999

      beta(v) = v/c
      Lorentz(v) = 1./sqrt(1-beta(v)**2)
    # note: gamma() cannot be used, is a gnuplot intrinsic function

    # Lorentz transformation of coordinates
    # from laboratory's reference system to
    # reference system where q is at rest
    # (suffix r indicates the reference system where q is at Rest)

      tr(x,y,z,t) = Lorentz(v)*(t+beta(v)*x)
      xr(x,y,z,t) = Lorentz(v)*(x+v*t)
      yr(x,y,z,t) = y
      zr(x,y,z,t) = z

    # E computed in reference where q is at rest (and B is zero):

      rsquare(xr,yr,zr) = xr**2+yr**2+zr**2
      r(xr,yr,zr) = sqrt(rsquare(xr,yr,zr))
      Er(xr,yr,zr,tr) = q/(4*pi*eps0)/rsquare(xr,yr,zr)
      Erx(xr,yr,zr,tr) = Er(xr,yr,zr,tr)*xr/r(xr,yr,zr)
      Ery(xr,yr,zr,tr) = Er(xr,yr,zr,tr)*yr/r(xr,yr,zr)
      Erz(xr,yr,zr,tr) = Er(xr,yr,zr,tr)*zr/r(xr,yr,zr)

    # Lorentz transformation of EM tensor to Laboratory' reference (SI units):
    #  E'x = Ex      
    #  E'y = gamma(Ey - v Bz )  (but Bz=0)
    #  E'z = gamma(Ez + v By )  (but By=0)
    #  B'x = Bx
    #  B'y = gamma(By + beta/c Ez )  (but By=0)
    #  B'z = gamma(Bz - beta/c Ey )  (but Bz=0)

      Ex(x,y,z,t) =  Erx(xr(x,y,z,t),yr(x,y,z,t),zr(x,y,z,t),tr(x,y,z,t))
      Ey(x,y,z,t) = Lorentz(v)*Ery(xr(x,y,z,t),yr(x,y,z,t),zr(x,y,z,t),tr(x,y,z,t))
      Ez(x,y,z,t) = Lorentz(v)*Erz(xr(x,y,z,t),yr(x,y,z,t),zr(x,y,z,t),tr(x,y,z,t))

      E(x,y,z,t) = sqrt (Ex(x,y,z,t)**2 + Ey(x,y,z,t)**2 + Ez(x,y,z,t)**2)

      Bx(x,y,z,t) = 0.
      By(x,y,z,t) = Lorentz(v)*(-beta(v)/c*Ez(x,y,z,t) )    
      Bz(x,y,z,t) = Lorentz(v)*(+beta(v)/c*Ey(x,y,z,t) )  

      B(x,y,z,t) = sqrt (Bx(x,y,z,t)**2 + By(x,y,z,t)**2 + Bz(x,y,z,t)**2)

    # graphic trick: fields goes to infinity approaching origin,
    # let's limit them to a max plottable value

      min(x,y) = (x < y) ? x : y
      Eplot(x,y,z,t) = min (1., E(x,y,z,t) )

    # graphic trick: B increases with v even in non-relativistic cases,
    # let's divide it by v so as to compare plots at different v.

      Bplot(x,y,z,t) = min (1., B(x,y,z,t)/v )

     set view map
     set size ratio -1
     unset surface
     set xrange [-1:1]
     set yrange [-1:1]
     set samples 500
     set isosamples 500
     set contour base
     set cntrparam levels auto 10

     splot Eplot(x,y,0,0), Bplot(x,y,0,0)


    Attached Files:

  8. Aug 31, 2013 #7


    User Avatar
    Gold Member

    Wow, this is really good and is amazing. I have to work all this out but I definately appreciate this. I couldn't find anything like the above anywhere.

    Albert Gauss
Know someone interested in this topic? Share this thread via Reddit, Google+, Twitter, or Facebook