uA709 op amp compensation

[Joseph M. Zias]

Most likely this can only be answered by an "old timer". I am making measurements on an uA709 op amp (metal can). I would like to calculate the frequency rolloff curves (I can measure them). I assume the compensation is via the miller effect. To do the calculations I would need to know the gain of the transistors and the effective resistance seen at the compensation terminals, not including the values I put there.
Anyone know those values?

 

[berkeman]

So you have the opamp schematic entered into SPICE and are looking for the transistor model data?

 

[Baluncore]

Anyone know those values?

Do you have the full circuit for the uA709, or just the simplified diagram ?
Resistor values are here: https://lh.pe/file/UA709CN(1).pdf

 

[Joseph M. Zias]

I have the schematic but not a spice program. Will have to look into getting one. However, using the open loop curves of Fairchild and doing some backtracking I find:
With C1=10pf and R1=0, the breakpoint looks to be 10khz. That would give an equivalent resistance working with C1 of 15.9 k ohms.
With C1=100pf and R1=1.5k, the breakpoint looks to be 1khz. That also equates to an equivalent resistance of 15.9 K ohms; makes sense as the frequency changes by x10 as does the capacitance.
The crossover frequency of the R1C1 is about 1 Mhz, so that does not come into play until the 2nd breakpoints.
So, assuming gains of 100 for the internal stage I get an R value of 15.9 k ohms. I don't see how to arrive at that given the schematic, but I don't know how to analyze it in that detail. I am of course just guessing on the gains.

 

[Baluncore]

Here is an LTspice model for the uA/LM709. At the end it defines the transistors used as all having the same specifications.

* LM709 SPICE Model
* Datasheet: http://www.national.com/ds.cgi/LM/LM709.pdf
* Helmut Sennewald
*
* Input compensation B (8) ---------------------\
* Input compensation A (1) ------------------\  |
* Output compensation (5) --------------\    |  |
* Output (6) -----------------------\   |    |  |
* Negative supply (4) ----------\   |   |    |  |
* Positive supply (7) --------\  |  |   |    |  |
* Inverting input (2) ----\   |  |  |   |    |  |
* non-inverting input(3)  |   |  |  |   |    |  |
*                     |   |   |  |  |   |    |  |
.subckt LM709         In+ In- V+ V- OUT COMP A  B
*
Q7 v+ N001 N005 0 NPN1
R5 v+ N001 10k
Q3 N001 N006 N003 0 NPN1
Q4 N001 N003 N002 0 NPN1
R1 N005 N006 25k
R3 N003 N004 3k
Q15 N004 N004 N002 0 NPN1
R2 N005 A 25k
Q2 A in- N007 0 NPN1
Q1 N006 in+ N007 0 NPN1
Q5 B A N009 0 NPN1
R4 N009 N004 3k
Q6 B N009 N002 0 NPN1
R6 v+ B 10k
R8 N002 N011 3.6k
R10 N011 N010 10k
Q10 N010 N010 V- 0 NPN1
Q11 N007 N010 N008 0 NPN1
R11 N008 V- 2.4k
R9 N012 N011 10k
Q8 v+ B N013 0 NPN1
R7 N013 N012 1k
Q9 comp N002 N012 0 PNP1
R13 N014 V- 75
R12 comp N014 10k
Q12 N015 comp N014 0 NPN1
Q13 V- N015 out 0 PNP1
Q14 v+ N015 out 0 NPN1
R14 v+ N015 20k
R15 N012 out 30k
.MODEL NPN1 NPN (BF=100 VAF=50 RB=100 CJE=4P CJC=2P CJS=2P TF=0.5N TR=10N)
.MODEL PNP1 PNP (BF=15 VAF=50 CJC=4P CJE=8P RB=100 TF=20N TR=200N)
.ends LM709

 

[Joseph M. Zias]

Here is an LTspice model for the uA/LM709. At the end it defines the transistors used as all having the same specifications.

* LM709 SPICE Model
* Datasheet: http://www.national.com/ds.cgi/LM/LM709.pdf
* Helmut Sennewald
*
* Input compensation B (8) ---------------------\
* Input compensation A (1) ------------------\  |
* Output compensation (5) --------------\    |  |
* Output (6) -----------------------\   |    |  |
* Negative supply (4) ----------\   |   |    |  |
* Positive supply (7) --------\  |  |   |    |  |
* Inverting input (2) ----\   |  |  |   |    |  |
* non-inverting input(3)  |   |  |  |   |    |  |
*                     |   |   |  |  |   |    |  |
.subckt LM709         In+ In- V+ V- OUT COMP A  B
*
Q7 v+ N001 N005 0 NPN1
R5 v+ N001 10k
Q3 N001 N006 N003 0 NPN1
Q4 N001 N003 N002 0 NPN1
R1 N005 N006 25k
R3 N003 N004 3k
Q15 N004 N004 N002 0 NPN1
R2 N005 A 25k
Q2 A in- N007 0 NPN1
Q1 N006 in+ N007 0 NPN1
Q5 B A N009 0 NPN1
R4 N009 N004 3k
Q6 B N009 N002 0 NPN1
R6 v+ B 10k
R8 N002 N011 3.6k
R10 N011 N010 10k
Q10 N010 N010 V- 0 NPN1
Q11 N007 N010 N008 0 NPN1
R11 N008 V- 2.4k
R9 N012 N011 10k
Q8 v+ B N013 0 NPN1
R7 N013 N012 1k
Q9 comp N002 N012 0 PNP1
R13 N014 V- 75
R12 comp N014 10k
Q12 N015 comp N014 0 NPN1
Q13 V- N015 out 0 PNP1
Q14 v+ N015 out 0 NPN1
R14 v+ N015 20k
R15 N012 out 30k
.MODEL NPN1 NPN (BF=100 VAF=50 RB=100 CJE=4P CJC=2P CJS=2P TF=0.5N TR=10N)
.MODEL PNP1 PNP (BF=15 VAF=50 CJC=4P CJE=8P RB=100 TF=20N TR=200N)
.ends LM709

Looks like I am going to have to get LT Spice downloaded.

 

[Baluncore]

Any SPICE will do with that code, but LTspice, now from ADI, is probably the best at the moment, and is free.
Also, subscribe to https://groups.io/g/LTspice which is great for help with running LTspice.

 

[Joseph M. Zias]

Looks like I am going to have to get LT Spice downloaded.

I have LT spice but I don't haven't been able to load this file into it. Can you give me some instructions on doing that?

 

[Baluncore]

Can you give me some instructions on doing that?

There are two ways.
1. You can simply copy the spice text into a .op spice directive box, then place that on the schematic page.
2. You can create a new filename.asy, (maybe explode and edit an older one), using the symbol editor. Place the spice text in a filename.sub circuit file with the same name as the filename.asy.
.lib, or .inc, to include a path to your files on the schematic, or place them in the \sym\ and \sub\ folders under lib somewhere on your system. My old system placed them at; C:\Program Files\LTC\LTspiceIV\lib\ ... but that might have changed.

 

[Joseph M. Zias]

Using method 1. I chose to have the operating point calculated. However, after choosing "run" the program says "This circuit does not contain a node other than node 0, gnd."

 

[Baluncore]

You need to comment out the *.subckt and *.ends to make the nodes and components in the model available on that schematic page. You can then connect it to external schematic by using the internal node names.

Attached is uA709.asc.txt which can be attached to a post because it is an ASCII text file. Save it, and rename it to uA709.asc and it will run under LTspice.

There is some problem with the file that causes an offset voltage and so a high input current. Maybe the substrate voltage? I will take another look when I have time.

 

[Baluncore]

Forget my previous post.
I have fixed a few bugs and got the uA709 / LM709 working as a 5kHz voltage follower. Attached are the .asc and .plt files you need to test it. You should be able to analyse the uA709 by modifying only the external circuit. Remember to remove the .txt extensions.
Here is the schematic of the .asc file, best viewed by in LTspice.