Is there a snubber circuit for SEPIC converter to solve MOSFET turn-off issue?

[sizz]

hello everyone,
I am designing Single ended primary inductor cell(SEPIC) converter. the objective is to get output voltage from 5V to 20V and 1 A current when we change the duty cycle of the pulse supplied to gate of MOSFET. when i simulated the circuit in proteus MOSFET is unable to turn off. I researched about snubber circuits as well but it didn't help me. Is there any snubber circuit for SEPIC converter? My calculation and simulation results are attached with it. please have a look and please help me.

thank you

 

[Kholdstare]

That's a big circuit. I'll solve it but it will take time. So, be patient. OK?

 

[sizz]

ok thankyou

 

[Kholdstare]

I've simulated your first circuit in pspice and I don't see any problem.
However the output current I got was 35mA.


Below is the SPICE code I used.
The diode and mosfet models are taken from datasheets.

** Creating circuit file "sepic-schematic1-trans.sim.cir"


.SUBCKT M_IRF540N 2 1 3
CA 12 8 1.95e-9
CB 15 14 1.90e-9
CIN 6 8 1.12e-9
DBODY 7 5 DBODYMOD
DBREAK 5 11 DBREAKMOD
DPLCAP 10 5 DPLCAPMOD
EBREAK 11 7 17 18 112.8
EDS 14 8 5 8 1
EGS 13 8 6 8 1
ESG 6 10 6 8 1
EVTHRES 6 21 19 8 1
EVTEMP 20 6 18 22 1
IT 8 17 1
LDRAIN 2 5 1.0e-9
LGATE 1 9 6.19e-9
LSOURCE 3 7 2.18e-9
MMED 16 6 8 8 MMEDMOD
MSTRO 16 6 8 8 MSTROMOD
MWEAK 16 21 8 8 MWEAKMOD
RBREAK 17 18 RBREAKMOD 1
RDRAIN 50 16 RDRAINMOD 2.00e-2
RGATE 9 20 1.77
RLDRAIN 2 5 10
RLGATE 1 9 26
RLSOURCE 3 7 11
RSLC1 5 51 RSLCMOD 1e-6
RSLC2 5 50 1e3
RSOURCE 8 7 RSOURCEMOD 6.5e-3
RVTHRES 22 8 RVTHRESMOD 1
RVTEMP 18 19 RVTEMPMOD 1
S1A 6 12 13 8 S1AMOD
S1B 13 12 13 8 S1BMOD
S2A 6 15 14 13 S2AMOD
S2B 13 15 14 13 S2BMOD
VBAT 22 19 DC 1
ESLC 51 50 VALUE={(V(5,51)/ABS(V(5,51)))*(PWR(V(5,51)/(1e-6*71),3.5))}
.MODEL DBODYMOD D (IS = 1.20e-12 RS = 4.2e-3 XTI = 5 TRS1 = 1.3e-3 TRS2 = 8.0e-6 CJO = 1.50e-9 TT = 7.47e-8 M = 0.63)
.MODEL DBREAKMOD D (RS = 4.2e-1 TRS1 = 8e-4 TRS2 = 3e-6)
.MODEL DPLCAPMOD D (CJO = 1.45e-9 IS = 1e-30 M = 0.82)
.MODEL MMEDMOD NMOS (VTO = 3.11 KP = 5 IS = 1e-30 N = 10 TOX = 1 L = 1u W = 1u RG = 1.77)
.MODEL MSTROMOD NMOS (VTO = 3.57 KP = 33.5 IS = 1e-30 N = 10 TOX = 1 L = 1u W = 1u)
.MODEL MWEAKMOD NMOS (VTO = 2.68 KP = 0.09 IS = 1e-30 N = 10 TOX = 1 L = 1u W = 1u RG = 17.7 )
.MODEL RBREAKMOD RES (TC1 =1.05e-3 TC2 = -5e-7)
.MODEL RDRAINMOD RES (TC1 = 9.40e-3 TC2 = 2.93e-5)
.MODEL RSLCMOD RES (TC1 = 3.5e-3 TC2 = 2.0e-6)
.MODEL RSOURCEMOD RES (TC1 = 1e-3 TC2 = 1e-6)
.MODEL RVTHRESMOD RES (TC1 = -1.8e-3 TC2 = -8.6e-6)
.MODEL RVTEMPMOD RES (TC1 = -3.0e-3 TC2 =1.5e-7)
.MODEL S1AMOD VSWITCH (RON = 1e-5 ROFF = 0.1 VON = -6.2 VOFF= -3.1)
.MODEL S1BMOD VSWITCH (RON = 1e-5 ROFF = 0.1 VON = -3.1 VOFF= -6.2)
.MODEL S2AMOD VSWITCH (RON = 1e-5 ROFF = 0.1 VON = -1.0 VOFF= 0.5)
.MODEL S2BMOD VSWITCH (RON = 1e-5 ROFF = 0.1 VON = 0.5 VOFF= -1.0)
.ENDS



.MODEL D_30LJQ045 d
+IS=3.01029e-08 RS=0.00758833 N=0.877045 EG=0.6
+XTI=0.5 BV=45 IBV=0.0001 CJO=2.65012e-09
+VJ=1.18451 M=0.511241 FC=0.5 TT=0
+KF=0 AF=1


* source SEPIC
R_R1 0 OUT 1k
C_C1 0 OUT 47u
C_C2 INT1 INT2 70u
L_L1 IN INT1 25u
L_L2 0 INT2 25u
C_C3 0 IN 2.2u
D_D1 INT2 OUT D_30LJQ045
V_V1 IN 0 5Vdc
V_V2 GATE 0
+PULSE 0 5 0ms 0.001ms 0.001ms 0.8ms 1ms
X_M1 INT1 GATE 0 M_IRF540N


*Analysis directives:
.TRAN 0 20ms 0
.PROBE


.END