Space-Time and Space-Space
Posted Oct1-10 at 12:07 PM by JDoolin
This is a demonstration of the effect of changing inertial reference frames. Please click on the thumbnails below for a preview.
In each image, the upper diagram is in two-diminsional Euclidian space (Space-vs-Space), while the lower diagram is in two dimensional Minkowskian spacetime (Space-vs-time).
I hope this demonstration makes clear some of the drastic changes that are implicit in a change of reference frame.
I have also submitted this to Mathematica's "Demonstration Project."
I should also highlight the importance of the event at (0,0) This is where the first signal from the two antennae meet. If you change the rapity while t=0, you will see that the same two signals are arriving, regardless of your rapidity. However, if you change the rapidity while t is NOT 0 you will be jumping to the reference frames of bodies which have traveled since time t=0, so your position is changing.
Whenever performing a Lorentz Transformation, take care to use a significant event as your origin, such as the location of a collision or acceleration.
In each image, the upper diagram is in two-diminsional Euclidian space (Space-vs-Space), while the lower diagram is in two dimensional Minkowskian spacetime (Space-vs-time).
I hope this demonstration makes clear some of the drastic changes that are implicit in a change of reference frame.
I have also submitted this to Mathematica's "Demonstration Project."
Code:
Clear["Global`*"]
origwL1 = {{0, -5}, {21, -5}};
origwL2 = {{0, 5}, {21, 5}};
slope[wL_] := (wL[[2]][[2]] - wL[[1]][[2]])/(wL[[2]][[1]] -
wL[[1]][[1]]);
curLocation[wL_, t_] := slope[wL] (t - wL[[1]][[1]]) + wL[[1]][[2]]
origsignals1 = Table[{t, curLocation[origwL1, t]}, {t, -5, 30, 1}];
origsignals2 = Table[{t, curLocation[origwL2, t]}, {t, -5, 30, 1}];
LT[theta_] := {{Cosh[theta], -Sinh[theta]}, {-Sinh[theta],
Cosh[theta]}};
Manipulate[
wL1 = Transpose[LT[rapidity].Transpose[origwL1]];
wL2 = Transpose[LT[rapidity].Transpose[origwL2]];
signals1 = Transpose[LT[rapidity].Transpose[origsignals1]];
signals2 = Transpose[LT[rapidity].Transpose[origsignals2]];
v1C = {signals1[[1]][[2]], signals1[[1]][[1]]};
v2C = {signals2[[1]][[2]], signals2[[1]][[1]]};
sz = 200;
v1L = v1C + {-sz, sz};
v1R = v1C + {sz, sz};
v2L = v2C + {-sz, sz};
v2R = v2C + {sz, sz};
GraphicsColumn[{(*start list*)
Graphics[
Join[
Table[
Circle[{signals1[[x]][[2]], 0},
Max[0, t - signals1[[x]][[1]]]](*circle*)
, {x, 1, Length[signals1]}](*table*),
Table[
Circle[{signals2[[x]][[2]], 0},
Max[0, t - signals2[[x]][[1]]]](*circle*)
, {x, 1, Length[signals2]}](*table*),
{PointSize[Medium], Point[{curLocation[wL1, t], 0}],
Point[{curLocation[wL2, t], 0}], Point[{0, 0}]
}](*join*)
, ImagePadding -> None, AxesOrigin -> {0, 0},
PlotRangeClipping -> True, PlotRangePadding -> None,
Axes -> True, AxesOrigin -> {0, 0},
PlotRange -> {{-20, 20}, {-10, 10}}](*graphics*)
, Graphics[
{
Line[{{curLocation[wL1, -sz], -sz}, {curLocation[wL1, sz], sz}}],
Line[{{curLocation[wL2, -sz], -sz}, {curLocation[wL2, sz], sz}}],
Point[v1C], Point[v2C],
Point[{curLocation[wL1, t], t}], Point[{curLocation[wL2, t], t}],
Point[{0, t}],
Line[{{-20, t}, {20, t}}],
Opacity[.3], Polygon[{v1C, v1L, v1R}], Polygon[{v2C, v2L, v2R}]
}
, ImagePadding -> None, AxesOrigin -> {0, 0},
PlotRangeClipping -> True, PlotRangePadding -> None, Axes -> True,
PlotRange -> {{-20, 20}, {t - 20, t + .1}}](*graphics*)
}(*end list*)
](*graphicscolumn*)
, {{t, 0}, -20, 20, .01}, {rapidity, -3, 3}](*manipulate*)
Whenever performing a Lorentz Transformation, take care to use a significant event as your origin, such as the location of a collision or acceleration.
Total Comments 0
